BMUG Revelations/BMUG Revelations.toast/Telecom/Scripts/ARA Modem Scripts/Glob Vlg PP⁄V.32 Pulse

Text File | 1992-02-05 | 3KB | 188 lines

! Global Village PowerPort/V.32 Modem - 11/17/91
! Global Village Communication, Inc., Menlo Park, California
! [phone]
!
! This version does pulse dialing
! Revised 2/5/92 to ignore dial tone and busy
!
@ORIGINATE
@ANSWER
!
@LABEL 1
serreset 9600, 0, 8, 1
dtrset
matchclr
settries 0
!
! first recall the factory configuration
!
@LABEL 2
matchstr 1 3 "OK\13\10"
write "AT\13"
matchread 30
inctries
iftries 3 59
! Modem is not responding, reset
DTRClear
pause 5
DTRSet
jump 2
!
! Next, Set up the configuration: turn off echo
!
@LABEL 3
matchstr 1 39 "OK\13\10"
write "AT&F\13"
matchread 40
pause 5
jump 2
!
@LABEL 39
matchstr 1 4 "OK\13\10"
write "ATE0X1&C1%C0\\N0\\Q2&D3\13"
matchread 30
jump 59
!
! If speaker on flag is true, jump to label 8.  Else turn off the speaker
@LABEL 4
hsreset 0 1 0 0 0 0
ifstr 2 8 "1"
matchstr 1 8 "OK\13\10"
write "ATM0\13"
matchread 30
jump 59
!
! The modem is ready.  So enable answering, or originate a call
!
@LABEL 8
ifANSWER 13
note "Dialing ^1" 3
write "ATS0=0DP^1\13"
!
@LABEL 9
matchstr 1 11 "CONNECT 4800\13\10"
matchstr 2 12 "CONNECT 9600\13\10"
matchstr 3 19 "CONNECT 2400\13\10"
matchstr 4 50 "NO CARRIER\13\10"
matchstr 5 59 "ERROR\13\10"
matchstr 6 52 "NO DIALTONE\13\10"
matchstr 7 53 "BUSY\13\10"
matchstr 8 54 "NO ANSWER\13\10"
matchread 700
jump 59
!
@LABEL 11
note "Modem connection established at 4800 bps" 2
setspeed 4800
jump 15
!
@LABEL 19
note "Modem connection established at 2400 bps" 2
setspeed 2400
jump 15
!
@LABEL 12
note "Modem connection established at 9600 bps" 2
!
@LABEL 15
ifANSWER 18
pause 30
@LABEL 18
exit 0
!
! @ANSWER
! Set up the modem to answer
@LABEL 13
write "ATS0=1\13"
matchstr 1 14 "OK\13\10"
matchread 30
jump 59
!
@LABEL 14
matchstr 1 20 "RING\13\10"
matchstr 2 11 "CONNECT 4800\13\10"
matchstr 3 12 "CONNECT 9600\13\10"
matchstr 4 19 "CONNECT 2400\13\10"
matchstr 5 50 "NO CARRIER\13\10"
matchstr 6 59 "ERROR\13\10"
matchstr 7 52 "NO DIALTONE\13\10"
matchstr 8 53 "BUSY\13\10"
matchstr 9 54 "NO ANSWER\13\10"
matchread 700
jump 14
!
@LABEL 20
userhook 1
note "Answering phone…" 2
jump 14
!
! 50: error messages
!
@LABEL 50
exit -6021
!
@LABEL 52
exit -6020
!
@LABEL 53
exit -6022
!
@LABEL 54
exit -6023
!
@LABEL 59
exit -6019
!
! Hang up the modem
!
@HANGUP
@LABEL 60
settries 0
@LABEL 61
matchclr
write "ATH0\13"
matchstr 1 64 "OK\13\10"
matchstr 2 63 "NO CARRIER\13\10"
matchstr 3 64 "ERROR\13\10"
matchread 30
inctries
iftries 3 63
! no response, try escape sequence
write "+++"
matchclr
matchstr 1 62 "OK\13\10"
matchread 15
! still no response, toggle DTR
DTRClear
pause 10
DTRSet
jump 61
!
@LABEL 62
pause 5
matchstr 1 64 "OK\13\10"
matchstr 2 63 "NO CARRIER\13\10"
write "ATH0\13"
matchread 60
jump 61
!
@LABEL 63
pause 45
Flush
!
! Recall the factory settings
!
@LABEL 64
matchclr
matchstr 1 65 "OK\13\10"
write "AT&F\13"
matchread 30
!
@LABEL 65
matchstr 1 66 "OK\13\10"
write "ATS0=0\13"
matchread 30
!
@LABEL 66
exit 0